tests(redshift-scheduler): implement stop operation

This commit adds end-to-end testing to validate the
AWS Lambda redshift scheduler actually works expected.
They key changes include:
* Created a new test-execution module that:
  * Triggers the aws stop lambda
  * Waits appropriate time intervals before and after function execution
  * Retrieves the redshift power states to verify function effectiveness

Author: diodonfrost

examples/redshift-scheduler/main.tf

@@ -6,14 +6,94 @@ resource "aws_kms_key" "scheduler" {
   deletion_window_in_days = 7
 }
 
+resource "aws_vpc" "redshift_vpc" {
+  cidr_block = "10.0.0.0/16"
+  tags = {
+    Name = "redshift-vpc-${random_pet.suffix.id}"
+  }
+}
+
+resource "aws_internet_gateway" "redshift_igw" {
+  vpc_id = aws_vpc.redshift_vpc.id
+  tags = {
+    Name = "redshift-igw-${random_pet.suffix.id}"
+  }
+}
+
+resource "aws_route_table" "redshift_route_table" {
+  vpc_id = aws_vpc.redshift_vpc.id
+
+  route {
+    cidr_block = "0.0.0.0/0"
+    gateway_id = aws_internet_gateway.redshift_igw.id
+  }
+
+  tags = {
+    Name = "redshift-rt-${random_pet.suffix.id}"
+  }
+}
+
+resource "aws_route_table_association" "redshift_rt_assoc_1" {
+  subnet_id      = aws_subnet.redshift_subnet_1.id
+  route_table_id = aws_route_table.redshift_route_table.id
+}
+
+resource "aws_route_table_association" "redshift_rt_assoc_2" {
+  subnet_id      = aws_subnet.redshift_subnet_2.id
+  route_table_id = aws_route_table.redshift_route_table.id
+}
+
+resource "aws_subnet" "redshift_subnet_1" {
+  vpc_id                  = aws_vpc.redshift_vpc.id
+  cidr_block              = "10.0.1.0/24"
+  availability_zone       = "eu-west-1a"
+  map_public_ip_on_launch = true
+}
+
+resource "aws_subnet" "redshift_subnet_2" {
+  vpc_id                  = aws_vpc.redshift_vpc.id
+  cidr_block              = "10.0.2.0/24"
+  availability_zone       = "eu-west-1b"
+  map_public_ip_on_launch = true
+}
+
+resource "aws_redshift_subnet_group" "redshift_subnet_group" {
+  name       = "redshift-subnet-group-${random_pet.suffix.id}"
+  subnet_ids = [aws_subnet.redshift_subnet_1.id, aws_subnet.redshift_subnet_2.id]
+}
+
+resource "aws_security_group" "redshift_sg" {
+  name        = "redshift-sg-${random_pet.suffix.id}"
+  description = "Security group for Redshift clusters"
+  vpc_id      = aws_vpc.redshift_vpc.id
+
+  ingress {
+    from_port   = 5439
+    to_port     = 5439
+    protocol    = "tcp"
+    cidr_blocks = ["0.0.0.0/0"]
+    description = "Allow Redshift access"
+  }
+
+  egress {
+    from_port   = 0
+    to_port     = 0
+    protocol    = "-1"
+    cidr_blocks = ["0.0.0.0/0"]
+  }
+}
+
 resource "aws_redshift_cluster" "scheduled" {
-  cluster_identifier  = "test-to-stop-${random_pet.suffix.id}"
-  database_name       = "mydb"
-  master_username     = "exampleuser"
-  master_password     = "Mustbe8characters"
-  node_type           = "dc2.large"
-  cluster_type        = "single-node"
-  skip_final_snapshot = true
+  cluster_identifier        = "test-to-stop-${random_pet.suffix.id}"
+  database_name             = "mydb"
+  master_username           = "exampleuser"
+  master_password           = "Mustbe8characters"
+  node_type                 = "dc2.large"
+  cluster_type              = "single-node"
+  publicly_accessible       = false
+  skip_final_snapshot       = true
+  cluster_subnet_group_name = aws_redshift_subnet_group.redshift_subnet_group.name
+  vpc_security_group_ids    = [aws_security_group.redshift_sg.id]
 
   tags = {
     tostop = "true"
@@ -26,13 +106,16 @@ resource "aws_redshift_cluster_snapshot" "scheduled" {
 }
 
 resource "aws_redshift_cluster" "not_scheduled" {
-  cluster_identifier  = "test-not-to-stop-${random_pet.suffix.id}"
-  database_name       = "mydb"
-  master_username     = "exampleuser"
-  master_password     = "Mustbe8characters"
-  node_type           = "dc2.large"
-  cluster_type        = "single-node"
-  skip_final_snapshot = true
+  cluster_identifier        = "test-not-to-stop-${random_pet.suffix.id}"
+  database_name             = "mydb"
+  master_username           = "exampleuser"
+  master_password           = "Mustbe8characters"
+  node_type                 = "dc2.large"
+  cluster_type              = "single-node"
+  publicly_accessible       = false
+  skip_final_snapshot       = true
+  cluster_subnet_group_name = aws_redshift_subnet_group.redshift_subnet_group.name
+  vpc_security_group_ids    = [aws_security_group.redshift_sg.id]
 
   tags = {
     tostop = "false"
@@ -71,3 +154,12 @@ module "redshift-start-monday" {
     value = "true"
   }
 }
+
+module "test-execution" {
+  count  = var.test_mode ? 1 : 0
+  source = "./test-execution"
+
+  lambda_stop_name                    = module.redshift-stop-friday.scheduler_lambda_name
+  redshift_cluster_to_scheduled_name  = aws_redshift_cluster.scheduled.cluster_identifier
+  redshift_cluster_not_scheduled_name = aws_redshift_cluster.not_scheduled.cluster_identifier
+}

examples/redshift-scheduler/outputs.tf

@@ -15,3 +15,11 @@ output "lambda_start_name" {
 output "lambda_start_arn" {
   value = module.redshift-start-monday.scheduler_lambda_arn
 }
+
+output "redshift_cluster_scheduled_identifier" {
+  value = aws_redshift_cluster.scheduled.cluster_identifier
+}
+
+output "redshift_cluster_not_scheduled_identifier" {
+  value = aws_redshift_cluster.not_scheduled.cluster_identifier
+}

examples/redshift-scheduler/terraform.tftest.hcl

@@ -1,6 +1,10 @@
 run "create_test_infrastructure" {
   command = apply
 
+  variables {
+    test_mode = true
+  }
+
   assert {
     condition     = module.redshift-stop-friday.scheduler_lambda_name == "stop-redshift-${random_pet.suffix.id}"
     error_message = "Invalid Stop lambda name"
@@ -10,4 +14,28 @@ run "create_test_infrastructure" {
     condition     = module.redshift-start-monday.scheduler_lambda_name == "start-redshift-${random_pet.suffix.id}"
     error_message = "Invalid Start lambda name"
   }
+
+  assert {
+    condition     = module.test-execution[0].redshift_cluster_to_scheduled_state == "pausing\n"
+    error_message = "Invalid Redshift cluster state"
+  }
+
+  assert {
+    condition     = module.test-execution[0].redshift_cluster_not_scheduled_state == "available\n"
+    error_message = "Invalid Redshift cluster state"
+  }
+}
+
+# Add this cleanup step to restore the cluster to 'available' state before destruction
+run "cleanup_test_resources" {
+  command = apply
+
+  variables {
+    redshift_cluster_name = run.create_test_infrastructure.redshift_cluster_scheduled_identifier
+  }
+
+  # This will start the stopped cluster to ensure proper deletion
+  module {
+    source = "./test-cleanup"
+  }
 }

examples/redshift-scheduler/test-cleanup/main.tf

@@ -0,0 +1,35 @@
+resource "null_resource" "start_docdb_cluster" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      TIMEOUT=600
+      START_TIME=$(date +%s)
+      
+      echo "Waiting for Redshift cluster ${var.redshift_cluster_name} to reach 'stopped' state (timeout: $TIMEOUT seconds)..."
+      
+      while true; do
+        # Check the current state of the DocumentDB cluster
+        CURRENT_STATE=$(aws redshift describe-clusters --cluster-identifier ${var.redshift_cluster_name} --query 'Clusters[0].ClusterStatus' --output text)
+        
+        # Get current elapsed time
+        CURRENT_TIME=$(date +%s)
+        ELAPSED=$((CURRENT_TIME - START_TIME))
+        
+        # Check if cluster is paused
+        if [ "$CURRENT_STATE" = "paused" ]; then
+          aws redshift start-cluster --cluster-identifier ${var.redshift_cluster_name}
+          exit 0
+        fi
+        
+        # Check if we've exceeded the timeout
+        if [ $ELAPSED -ge $TIMEOUT ]; then
+          echo "Timeout reached. Redshift cluster did not reach 'paused' state within $TIMEOUT seconds."
+          exit 1
+        fi
+        
+        # Wait 10 seconds before checking again
+        echo "Current state: $CURRENT_STATE (elapsed: $ELAPSED seconds/ $TIMEOUT seconds)..."
+        sleep 10
+      done
+    EOT
+  }
+}

examples/redshift-scheduler/test-cleanup/variables.tf

@@ -0,0 +1,4 @@
+variable "redshift_cluster_name" {
+  description = "Name of the Redshift cluster to start before deletion"
+  type        = string
+}

examples/redshift-scheduler/test-execution/main.tf

@@ -0,0 +1,58 @@
+resource "time_sleep" "before_stop_wait_240_seconds" {
+  create_duration = "240s"
+}
+
+resource "aws_lambda_invocation" "stop_redshift" {
+  function_name = var.lambda_stop_name
+
+  input = jsonencode({
+    key1 = "value1"
+    key2 = "value2"
+  })
+
+  depends_on = [time_sleep.before_stop_wait_240_seconds]
+}
+
+resource "time_sleep" "after_stop_wait_60_seconds" {
+  create_duration = "60s"
+
+  depends_on = [aws_lambda_invocation.stop_redshift]
+}
+
+resource "null_resource" "redshift_cluster_to_scheduled" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      aws redshift describe-clusters \
+        --cluster-identifier ${var.redshift_cluster_to_scheduled_name} \
+        --query 'Clusters[0].ClusterStatus' \
+        --output text > ${path.module}/redshift_cluster_to_scheduled.state
+    EOT
+  }
+
+  depends_on = [time_sleep.after_stop_wait_60_seconds]
+}
+
+data "local_file" "redshift_cluster_to_scheduled" {
+  filename = "${path.module}/redshift_cluster_to_scheduled.state"
+
+  depends_on = [null_resource.redshift_cluster_to_scheduled]
+}
+
+resource "null_resource" "redshift_cluster_not_scheduled" {
+  provisioner "local-exec" {
+    command = <<-EOT
+      aws redshift describe-clusters \
+        --cluster-identifier ${var.redshift_cluster_not_scheduled_name} \
+        --query 'Clusters[0].ClusterStatus' \
+        --output text > ${path.module}/redshift_cluster_not_scheduled.state
+    EOT
+  }
+
+  depends_on = [time_sleep.after_stop_wait_60_seconds]
+}
+
+data "local_file" "redshift_cluster_not_scheduled" {
+  filename = "${path.module}/redshift_cluster_not_scheduled.state"
+
+  depends_on = [null_resource.redshift_cluster_not_scheduled]
+}

examples/redshift-scheduler/test-execution/outputs.tf

@@ -0,0 +1,9 @@
+output "redshift_cluster_to_scheduled_state" {
+  description = "State of the Redshift cluster that should be stopped"
+  value       = data.local_file.redshift_cluster_to_scheduled.content
+}
+
+output "redshift_cluster_not_scheduled_state" {
+  description = "State of the Redshift cluster that should not be stopped"
+  value       = data.local_file.redshift_cluster_not_scheduled.content
+} 

examples/redshift-scheduler/test-execution/variables.tf

@@ -0,0 +1,14 @@
+variable "lambda_stop_name" {
+  description = "Name of the lambda function to stop Redshift clusters"
+  type        = string
+}
+
+variable "redshift_cluster_to_scheduled_name" {
+  description = "Name of the Redshift cluster that should be stopped"
+  type        = string
+}
+
+variable "redshift_cluster_not_scheduled_name" {
+  description = "Name of the Redshift cluster that should not be stopped"
+  type        = string
+}

examples/redshift-scheduler/test-execution/versions.tf

@@ -0,0 +1,21 @@
+terraform {
+  required_version = ">= 1.3.0"
+  required_providers {
+    aws = {
+      source  = "hashicorp/aws"
+      version = ">= 5.94.1"
+    }
+    null = {
+      source  = "hashicorp/null"
+      version = ">= 3.0.0, < 4.0"
+    }
+    local = {
+      source  = "hashicorp/local"
+      version = ">= 2.0.0, < 3.0"
+    }
+    time = {
+      source  = "hashicorp/time"
+      version = "0.13.0"
+    }
+  }
+}

examples/redshift-scheduler/variables.tf

@@ -0,0 +1,5 @@
+variable "test_mode" {
+  description = "Whether to run in test mode"
+  type        = bool
+  default     = false
+}