feat: CCIP hook and ism

.changeset/mean-cherries-reflect.md

@@ -0,0 +1,5 @@
+---
+'@hyperlane-xyz/core': minor
+---
+
+Implement CCIP hook and ISM

solidity/contracts/hooks/CCIPHook.sol

@@ -0,0 +1,83 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {AbstractMessageIdAuthHook} from "./libs/AbstractMessageIdAuthHook.sol";
+import {Message} from "../libs/Message.sol";
+import {TypeCasts} from "../libs/TypeCasts.sol";
+
+// ============ External Imports ============
+import {IRouterClient} from "@chainlink/contracts-ccip/src/v0.8/ccip/interfaces/IRouterClient.sol";
+import {Client} from "@chainlink/contracts-ccip/src/v0.8/ccip/libraries/Client.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title CCIPHook
+ * @notice Message hook to inform the CCIP of messages published through CCIP.
+ */
+contract CCIPHook is AbstractMessageIdAuthHook {
+    using Message for bytes;
+    using TypeCasts for bytes32;
+
+    IRouterClient internal immutable ccipRouter;
+    uint64 public immutable ccipDestination;
+
+    // ============ Constructor ============
+
+    constructor(
+        address _ccipRouter,
+        uint64 _ccipDestination,
+        address _mailbox,
+        uint32 _destination,
+        bytes32 _ism
+    ) AbstractMessageIdAuthHook(_mailbox, _destination, _ism) {
+        ccipDestination = _ccipDestination;
+        ccipRouter = IRouterClient(_ccipRouter);
+    }
+
+    // ============ Internal functions ============
+
+    function _buildCCIPMessage(
+        bytes calldata message
+    ) internal view returns (Client.EVM2AnyMessage memory) {
+        // Create an EVM2AnyMessage struct in memory with necessary information for sending a cross-chain message
+        return
+            Client.EVM2AnyMessage({
+                receiver: abi.encode(ism),
+                data: abi.encode(message.id()),
+                tokenAmounts: new Client.EVMTokenAmount[](0),
+                extraArgs: "",
+                feeToken: address(0)
+            });
+    }
+
+    function _quoteDispatch(
+        bytes calldata /*metadata*/,
+        bytes calldata message
+    ) internal view override returns (uint256) {
+        Client.EVM2AnyMessage memory ccipMessage = _buildCCIPMessage(message);
+
+        return ccipRouter.getFee(ccipDestination, ccipMessage);
+    }
+
+    function _sendMessageId(
+        bytes calldata /*metadata*/,
+        bytes calldata message
+    ) internal override {
+        Client.EVM2AnyMessage memory ccipMessage = _buildCCIPMessage(message);
+
+        ccipRouter.ccipSend{value: msg.value}(ccipDestination, ccipMessage);
+    }
+}

solidity/contracts/isms/hook/CCIPIsm.sol

@@ -0,0 +1,70 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+
+import {IInterchainSecurityModule} from "../../interfaces/IInterchainSecurityModule.sol";
+import {Message} from "../../libs/Message.sol";
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {AbstractMessageIdAuthorizedIsm} from "./AbstractMessageIdAuthorizedIsm.sol";
+
+// ============ External Imports ============
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+import {IRouterClient} from "@chainlink/contracts-ccip/src/v0.8/ccip/interfaces/IRouterClient.sol";
+import {Client} from "@chainlink/contracts-ccip/src/v0.8/ccip/libraries/Client.sol";
+import {CCIPReceiver} from "@chainlink/contracts-ccip/src/v0.8/ccip/applications/CCIPReceiver.sol";
+
+/**
+ * @title CCIPIsm
+ * @notice Uses CCIP hook to verify interchain messages.
+ */
+contract CCIPIsm is AbstractMessageIdAuthorizedIsm, CCIPReceiver {
+    using TypeCasts for bytes32;
+
+    // ============ Constants ============
+
+    uint8 public constant moduleType =
+        uint8(IInterchainSecurityModule.Types.NULL);
+
+    uint64 public immutable ccipOrigin;
+
+    // ============ Storage ============
+    constructor(
+        address _ccipRouter,
+        uint64 _ccipOrigin
+    ) CCIPReceiver(_ccipRouter) {
+        ccipOrigin = _ccipOrigin;
+    }
+
+    // ============ Internal functions ============
+    function _ccipReceive(
+        Client.Any2EVMMessage memory any2EvmMessage
+    ) internal override {
+        require(
+            ccipOrigin == any2EvmMessage.sourceChainSelector,
+            "Unauthorized origin"
+        );
+
+        bytes32 sender = abi.decode(any2EvmMessage.sender, (bytes32));
+        require(sender == authorizedHook, "Unauthorized hook");
+
+        bytes32 messageId = abi.decode(any2EvmMessage.data, (bytes32));
+        preVerifyMessage(messageId, msg.value);
+    }
+
+    function _isAuthorized() internal view override returns (bool) {
+        return msg.sender == getRouter();
+    }
+}

solidity/hardhat.config.cts

@@ -10,7 +10,7 @@ import 'solidity-coverage';
  */
 module.exports = {
   solidity: {
-    version: '0.8.19',
+    version: '0.8.22',
     settings: {
       optimizer: {
         enabled: true,

solidity/package.json

@@ -4,6 +4,7 @@
   "version": "5.11.3",
   "dependencies": {
     "@arbitrum/nitro-contracts": "^1.2.1",
+    "@chainlink/contracts-ccip": "^1.5.0",
     "@eth-optimism/contracts": "^0.6.0",
     "@hyperlane-xyz/utils": "8.6.1",
     "@layerzerolabs/lz-evm-oapp-v2": "2.0.2",

solidity/remappings.txt

@@ -2,6 +2,7 @@
 @eth-optimism=../node_modules/@eth-optimism
 @layerzerolabs=../node_modules/@layerzerolabs
 @openzeppelin=../node_modules/@openzeppelin
+@chainlink=../node_modules/@chainlink
 ds-test/=lib/forge-std/lib/ds-test/src/
 forge-std/=lib/forge-std/src/
 fx-portal/=lib/fx-portal/